SVERWEIS einfach erklärt und direkt geübt
SVERWEIS sucht einen Wert in der ersten Spalte einer Tabelle und gibt einen Wert aus derselben Zeile zurück. Zum Beispiel den Preis zu einer Artikelnummer.
Kurz gesagt: =SVERWEIS(Suchwert;Tabelle;Spaltennummer;FALSCH). Die Suche findet immer in der ersten Spalte der Tabelle statt, die Spaltennummer zählt ab dieser Spalte, und FALSCH steht für eine genaue Suche.
Probier es gleich aus
In der Tabelle steht eine Preisliste. Gesucht ist der Preis zu der Artikelnummer in E2. Klick in die gelbe Zelle und schreib die Formel. Wenn du beim Tippen auf eine Zelle klickst, wird ihr Bezug eingefügt.
Aufgabe Finde in F2 mit SVERWEIS den Preis des Artikels, dessen Nummer in E2 steht.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Artikelnr. | Artikel | Preis € | Gesucht | Preis | |
| 2 | A-101 | Kugelschreiber | 4,9 | A-104 | ||
| 3 | A-104 | Tacker | 19,9 | |||
| 4 | A-103 | Notizblock | 7,2 | |||
| 5 | A-102 | Ordner | 12,5 | |||
| 6 | A-105 | Radiergummi | 3,4 |
So ist SVERWEIS aufgebaut
| Argument | Bedeutung | Im Beispiel |
|---|---|---|
| Suchkriterium | Der Wert, den du suchst | E2 (die Artikelnummer) |
| Matrix | Die Tabelle, in der gesucht wird. Die erste Spalte muss die Suchwerte enthalten. | A2:C6 |
| Spaltenindex | Aus welcher Spalte der Tabelle das Ergebnis kommt, gezählt ab der ersten Spalte der Matrix | 3 (Preis) |
| Bereich_Verweis | FALSCH für eine genaue Suche, WAHR oder leer für eine ungefähre Suche in sortierten Daten | FALSCH |
Die komplette Formel lautet also =SVERWEIS(E2;A2:C6;3;FALSCH). Excel sucht A-104 in A2:A6, findet die Nummer in Zeile 3, geht dort in die dritte Spalte und gibt 19,90 zurück. Die Liste ist nicht sortiert, deshalb ist FALSCH am Ende wichtig.
Noch eine Übung: Abteilung zur Personalnummer
Ein typischer Fall aus der Personalabteilung. Diesmal ist das Suchkriterium eine Zahl.
Aufgabe In F2 soll die Abteilung der Person stehen, deren Personalnummer in E2 steht.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Personalnr. | Name | Abteilung | Personalnr. | Abteilung | |
| 2 | 1012 | Murat Kaya | Vertrieb | 1031 | ||
| 3 | 1007 | Jana Weber | Einkauf | |||
| 4 | 1023 | Lena Hoffmann | Controlling | |||
| 5 | 1044 | Sara Klein | Vertrieb | |||
| 6 | 1031 | Tom Schulz | Personal |
Diese Übung gehört zu Premium.
Mit Premium öffnest du alle Übungen jeder Lektion, übst unbegrenzt mit neuen Aufgaben und kannst den Abschlusstest mit Zertifikat machen.
Premium ansehen Schon Premium? Anmelden
Die erste Übung dieser Lektion ist kostenlos.
Typische Fehler bei SVERWEIS
Ergebnis #NV
#NV heißt „nicht vorhanden“. Excel hat den Suchwert in der ersten Spalte nicht gefunden. Häufige Gründe sind Tippfehler, Leerzeichen am Ende eines Eintrags oder Zahlen, die als Text gespeichert sind. Wenn ein fehlender Wert normal ist, kannst du die Formel in WENNFEHLER einpacken: =WENNFEHLER(SVERWEIS(E2;A2:C6;3;FALSCH);"nicht gefunden").
FALSCH am Ende vergessen
Ohne das vierte Argument sucht SVERWEIS ungefähr. Bei unsortierten Daten liefert die Formel dann oft ein falsches Ergebnis, ohne dass eine Fehlermeldung erscheint. Für Artikelnummern, Namen und IDs gehört deshalb immer FALSCH ans Ende. Wofür die ungefähre Suche gedacht ist, zeigt die Seite SVERWEIS mit Staffel.
Die Suchspalte steht nicht ganz links
SVERWEIS kann nur in der ersten Spalte der Matrix suchen. Steht der Suchwert weiter rechts, musst du die Matrix so wählen, dass sie mit dieser Spalte beginnt. Werte links davon erreichst du mit SVERWEIS gar nicht. Dafür gibt es XVERWEIS oder INDEX mit VERGLEICH.
Falsche Spaltennummer
Die Spaltennummer zählt ab der ersten Spalte der Matrix, nicht ab Spalte A des Tabellenblatts. Beginnt die Matrix in Spalte C, ist Spalte E die Nummer 3.
Bezüge verrutschen beim Kopieren
Wenn du die Formel nach unten ziehst, wandert die Matrix mit. Setz Dollarzeichen, damit sie fest bleibt: =SVERWEIS(E2;$A$2:$C$6;3;FALSCH).
SVERWEIS auf Englisch
In der englischen Excel-Version heißt SVERWEIS VLOOKUP, und die Argumente werden mit Komma statt Semikolon getrennt. Aus FALSCH wird FALSE:
| Deutsch | Englisch |
|---|---|
=SVERWEIS(E2;A2:C6;3;FALSCH) | =VLOOKUP(E2,A2:C6,3,FALSE) |
| WVERWEIS (waagerecht) | HLOOKUP |
| WENNFEHLER | IFERROR |
Unsere Übungen verstehen beide Schreibweisen. Unter jeder Übung stellst du ein, welche Sprache dein Excel hat.
Mit Power Query statt Formel
Bei großen oder regelmäßig neuen Listen kannst du das Nachschlagen auch in Power Query erledigen. Der Befehl Abfragen zusammenführen verknüpft zwei Tabellen über eine Schlüsselspalte, ganz ohne Spaltenindex und ohne #NV. Fehlende Treffer erscheinen als leere Werte. Schritt für Schritt erklärt: SVERWEIS in Power Query.
In welchen Excel-Versionen gibt es SVERWEIS?
SVERWEIS gibt es in allen Excel-Versionen, auch in Excel 2016 und 2019, in Excel für Mac und in Excel für das Web. Wenn du Microsoft 365, Excel 2021 oder Excel 2024 hast, lohnt sich ein Blick auf XVERWEIS. Die Funktion ist einfacher und hat weniger Fallstricke.
SVERWEIS oder XVERWEIS?
XVERWEIS sucht standardmäßig genau, braucht keine Spaltennummer, kann auch nach links suchen und hat ein eigenes Argument für den Fall, dass nichts gefunden wird. SVERWEIS bleibt trotzdem wichtig: Er steckt in unzähligen bestehenden Dateien, funktioniert in jeder Version und wird in Bewerbungstests weiterhin oft abgefragt.
Häufige Fragen
Was bedeutet das S in SVERWEIS?
S steht für senkrecht. SVERWEIS sucht von oben nach unten in einer Spalte. Sein Gegenstück WVERWEIS sucht waagerecht in einer Zeile.
Kann SVERWEIS mehrere Suchkriterien?
Nicht direkt. Üblich ist eine Hilfsspalte, die die Kriterien verbindet, zum Beispiel =A2&"-"&B2, und ein SVERWEIS auf diese Spalte. Mit XVERWEIS geht es ohne Hilfsspalte. Schritt für Schritt erklärt: SVERWEIS mit mehreren Kriterien.
Warum gibt SVERWEIS 0 statt eines leeren Feldes zurück?
Ist die gefundene Zelle leer, gibt SVERWEIS 0 zurück. Wenn du lieber ein leeres Feld möchtest, häng &"" an die Formel an. Das Ergebnis ist dann allerdings Text.