ZÄHLENWENN einfach erklärt und direkt geübt

Kurz gesagt: =ZÄHLENWENN(Bereich;Suchkriterien). Excel prüft jede Zelle im Bereich und zählt die, auf die das Kriterium passt. Text und Vergleiche stehen in Anführungszeichen.

Probier es gleich aus

Die Tabelle listet Bestellungen mit Stadt und Umsatz. Gesucht ist die Anzahl der Bestellungen aus Hamburg. Klick in die gelbe Zelle und schreib die Formel. Wenn du beim Tippen einen Bereich markierst, wird sein Bezug eingefügt.

Aufgabe Zähle in E2 mit ZÄHLENWENN, wie viele Bestellungen aus Hamburg kommen.

	A	B	C	D	E
1	Bestellnr.	Stadt	Umsatz €		Bestellungen aus Hamburg
2	B-2201	Hamburg	340
3	B-2202	Berlin	1280
4	B-2203	Hamburg	760
5	B-2204	Köln	95
6	B-2205	Hamburg	2150
7	B-2206	Berlin	480
8	B-2207	München	610

So ist ZÄHLENWENN aufgebaut

Argument	Bedeutung	Im Beispiel
Bereich	Die Zellen, die geprüft und gezählt werden	B2:B8 (die Städte)
Suchkriterien	Die Bedingung, die eine Zelle erfüllen muss: ein Text, eine Zahl, ein Vergleich oder ein Zellbezug	"Hamburg"

Die komplette Formel lautet =ZÄHLENWENN(B2:B8;"Hamburg") und ergibt 3. Groß- und Kleinschreibung spielt keine Rolle, „hamburg“ würde genauso gezählt.

Kriterien richtig schreiben

Das Kriterium ist der eigentliche Kern von ZÄHLENWENN. Diese Schreibweisen brauchst du im Alltag:

Kriterium	Zählt Zellen, die …
"Berlin"	genau Berlin enthalten
"<>Berlin"	nicht Berlin enthalten (auch leere Zellen)
">5"	eine Zahl größer als 5 enthalten
">=1000"	eine Zahl ab 1000 enthalten, 1000 selbst eingeschlossen
"B*"	mit B beginnen. Das Sternchen steht für beliebig viele Zeichen.
"*GmbH*"	irgendwo GmbH enthalten
"M??er"	fünf Zeichen lang sind, mit M beginnen und auf er enden, etwa Meier oder Maier. Das Fragezeichen steht für genau ein Zeichen.
""	leer sind

Soll der Grenzwert aus einer Zelle kommen, verbindest du den Vergleich mit dem Zellbezug über das &-Zeichen: =ZÄHLENWENN(C2:C8;">"&E2). Der Vergleichsoperator steht in Anführungszeichen, der Bezug nicht. Geht es nur um Gleichheit, reicht der Bezug allein: =ZÄHLENWENN(B2:B8;E2).

Noch eine Übung: Rechnungen ab 1.000 €

Jetzt zählst du keine Texte, sondern Beträge, die eine Grenze erreichen. Achte darauf, ob 1.000 € selbst mitzählen soll.

Aufgabe Zähle in E2, wie viele Rechnungen einen Betrag von mindestens 1.000 € haben.

	A	B	C	D	E
1	Rechnung	Kunde	Betrag €		Rechnungen ab 1.000 €
2	R-1041	Becker GmbH	850
3	R-1042	Schulz AG	1200
4	R-1043	Hofmann KG	1000
5	R-1044	Wagner GmbH	430
6	R-1045	Schulz AG	2300
7	R-1046	Krüger OHG	990
8	R-1047	Becker GmbH	1500

Mehrere Bedingungen: ZÄHLENWENNS

ZÄHLENWENN kennt nur ein Kriterium. Für mehrere Bedingungen gibt es ZÄHLENWENNS. Du gibst einfach Paare aus Bereich und Kriterium an, und gezählt wird nur, wenn alle Bedingungen in derselben Zeile stimmen:

=ZÄHLENWENNS(B2:B8;"Hamburg";C2:C8;">=500") zählt Bestellungen aus Hamburg mit mindestens 500 € Umsatz. Mit demselben Bereich zweimal grenzt du einen Zahlenbereich ein: =ZÄHLENWENNS(C2:C8;">=500";C2:C8;"<=1000"). Wenn du statt zu zählen addieren willst, ist SUMMEWENNS das passende Gegenstück. Datumsbereiche, Kriterien aus Zellen und eigene Übungen dazu findest du auf der Seite ZÄHLENWENNS.

Typische Fehler bei ZÄHLENWENN

Kriterium ohne Anführungszeichen

Vergleiche und Texte müssen in Anführungszeichen stehen. =ZÄHLENWENN(C2:C8;>=1000) lehnt Excel direkt beim Eingeben ab. =ZÄHLENWENN(B2:B8;Hamburg) ergibt #NAME?, weil Excel Hamburg für einen Namen hält. Nur reine Zahlen und Zellbezüge kommen ohne Anführungszeichen aus.

Der Bezug steht in den Anführungszeichen

">E2" vergleicht mit dem Text „E2“, nicht mit dem Inhalt der Zelle. Richtig ist ">"&E2.

Leerzeichen in den Daten

Steht in einer Zelle „Hamburg “ mit Leerzeichen am Ende, zählt das Kriterium "Hamburg" sie nicht mit. Solche Leerzeichen sind unsichtbar und stammen oft aus Exporten. Abhilfe schafft eine Hilfsspalte mit =GLÄTTEN(B2) oder ein Kriterium mit Sternchen wie "Hamburg*".

Unterschiedlich große Bereiche in ZÄHLENWENNS

Alle Bereiche in ZÄHLENWENNS müssen gleich viele Zeilen und Spalten haben. =ZÄHLENWENNS(B2:B8;"Hamburg";C2:C9;">500") ergibt #WERT!, weil der zweite Bereich eine Zeile länger ist.

> statt >=

">1000" zählt 1000 selbst nicht mit. Wenn die Aufgabe „ab“ oder „mindestens“ sagt, brauchst du ">=1000".

ZÄHLENWENN auf Englisch

In der englischen Excel-Version heißt ZÄHLENWENN COUNTIF, und die Argumente werden mit Komma statt Semikolon getrennt. Die Kriterien selbst schreibst du gleich:

Deutsch	Englisch
=ZÄHLENWENN(B2:B8;"Hamburg")	=COUNTIF(B2:B8,"Hamburg")
ZÄHLENWENNS	COUNTIFS
GLÄTTEN	TRIM

Unsere Übungen verstehen beide Schreibweisen. Unter jeder Übung stellst du ein, welche Sprache dein Excel hat.

In welchen Excel-Versionen gibt es ZÄHLENWENN?

ZÄHLENWENN und ZÄHLENWENNS gibt es in allen aktuellen Excel-Versionen, also in Microsoft 365, Excel 2016, 2019, 2021 und 2024, in Excel für Mac und in Excel für das Web.

Häufige Fragen