INDEX und VERGLEICH einfach erklärt und direkt geübt

Kurz gesagt: =INDEX(Ergebnisspalte;VERGLEICH(Suchwert;Suchspalte;0)). VERGLEICH liefert die Zeile, in der der Suchwert steht, INDEX gibt den Wert aus dieser Zeile der Ergebnisspalte zurück. Die 0 steht für eine genaue Suche.

Probier es gleich aus

In der Tabelle stehen Mitarbeitende mit Personalnummer, Name und Abteilung. Gesucht ist die Personalnummer zu dem Namen in E2. Die Nummer steht links vom Namen, mit SVERWEIS kommst du hier also nicht weiter. Klick in die gelbe Zelle und schreib die Formel.

Aufgabe Finde in F2 die Personalnummer der Person, deren Name in E2 steht. Die Nummer steht links vom Namen, nimm deshalb INDEX und VERGLEICH.

	A	B	C	D	E	F
1	Personalnr.	Name	Abteilung		Name	Personalnr.
2	1012	Murat Kaya	Vertrieb		Sara Klein
3	1007	Jana Weber	Einkauf
4	1023	Lena Hoffmann	Controlling
5	1044	Sara Klein	Vertrieb
6	1031	Tom Schulz	Personal
7	1019	Ali Demir	Einkauf

So ist INDEX mit VERGLEICH aufgebaut

Argument	Bedeutung	Im Beispiel
Matrix (INDEX)	Die Spalte, aus der das Ergebnis kommt	A2:A7 (Personalnummern)
Suchkriterium (VERGLEICH)	Der Wert, den du suchst	E2 (der Name)
Suchmatrix (VERGLEICH)	Die Spalte, in der gesucht wird	B2:B7 (Namen)
Vergleichstyp (VERGLEICH)	0 für eine genaue Suche	0

Excel rechnet von innen nach außen. VERGLEICH(E2;B2:B7;0) sucht Sara Klein in B2:B7 und liefert 4, weil der Name an vierter Stelle steht. Aus der Formel wird damit =INDEX(A2:A7;4), und INDEX gibt den vierten Wert aus A2:A7 zurück: 1044.

INDEX allein: der Wert an einer Position

INDEX sucht nichts, sondern bekommt eine Position. Die Syntax lautet =INDEX(Matrix;Zeile;[Spalte]). =INDEX(A2:C7;4;3) geht in A2:C7 zur vierten Zeile und dritten Spalte und liefert den Inhalt von C5. Gezählt wird ab dem Anfang des Bereichs, nicht ab Zeile 1 des Tabellenblatts. Besteht die Matrix nur aus einer Spalte, lässt du die Spaltennummer weg.

VERGLEICH allein: die Position eines Werts

VERGLEICH arbeitet andersherum: Du gibst einen Wert vor und bekommst seine Position. Die Syntax lautet =VERGLEICH(Suchkriterium;Suchmatrix;[Vergleichstyp]). Der Vergleichstyp legt fest, wie gesucht wird:

Vergleichstyp	Findet	Voraussetzung
0	genau den Suchwert	keine, die Reihenfolge ist egal
1 oder leer	den größten Wert, der kleiner oder gleich dem Suchwert ist	Daten aufsteigend sortiert
-1	den kleinsten Wert, der größer oder gleich dem Suchwert ist	Daten absteigend sortiert

Für Namen, Nummern und IDs nimmst du fast immer 0. Typ 1 passt zu Staffeln, etwa Rabattstufen, die ab einer bestimmten Menge gelten.

Noch eine Übung: Platz in der Rangliste

Die Verkaufsliste ist nach Umsatz sortiert. VERGLEICH allein verrät dir, auf welchem Platz eine Person steht.

Aufgabe Die Liste ist nach Umsatz sortiert, der Beste steht oben. Ermittle in F2 mit VERGLEICH, auf welchem Platz die Person aus E2 steht.

	A	B	C	D	E	F
1	Name	Umsatz €			Name	Platz
2	Sara Klein	48200			Lena Hoffmann
3	Murat Kaya	45900
4	Lena Hoffmann	41300
5	Tom Schulz	38750
6	Jana Weber	36100
7	Ali Demir	29400

Warum INDEX und VERGLEICH besser ist als SVERWEIS

Suche nach links

SVERWEIS sucht immer in der ersten Spalte der Matrix und gibt nur Werte rechts davon zurück. Bei INDEX und VERGLEICH sind Suchspalte und Ergebnisspalte zwei getrennte Bereiche. Wie sie zueinander liegen, spielt keine Rolle.

Eingefügte Spalten zerstören nichts

In =SVERWEIS(E2;A2:D7;4;FALSCH) steht die 4 als feste Zahl. Fügt jemand eine Spalte in die Tabelle ein, zeigt die Formel auf die falsche Spalte, und zwar ohne Fehlermeldung. INDEX und VERGLEICH arbeiten nur mit Bezügen, und die passt Excel beim Einfügen automatisch an.

Zweidimensional suchen: INDEX mit zwei VERGLEICH

Stell dir eine Umsatztabelle vor: Regionen in A2:A6, Monate in B1:M1, die Umsätze in B2:M6. Ein VERGLEICH liefert die Zeile, ein zweiter die Spalte, und INDEX gibt den Wert am Kreuzungspunkt zurück:

=INDEX(B2:M6;VERGLEICH(O2;A2:A6;0);VERGLEICH(P2;B1:M1;0))

Steht in O2 „Süd“ und in P2 „März“, liefert die Formel den Märzumsatz der Region Süd. Der Zeilenbereich muss dabei genauso hoch sein wie die Matrix, der Spaltenbereich genauso breit.

Typische Fehler bei INDEX und VERGLEICH

Die 0 bei VERGLEICH vergessen

Ohne drittes Argument sucht VERGLEICH mit Typ 1, also ungefähr in sortierten Daten. In einer unsortierten Liste kommt dann oft eine falsche Position heraus, ohne Fehlermeldung. Schreib die 0 deshalb immer aus.

Bereiche unterschiedlich groß

Suchspalte und Ergebnisspalte müssen in derselben Zeile beginnen und gleich lang sein. =INDEX(A1:A7;VERGLEICH(E2;B2:B7;0)) liefert immer den Wert eine Zeile zu weit oben, weil INDEX ab Zeile 1 zählt und VERGLEICH ab Zeile 2. Ist der Suchbereich länger als die Matrix von INDEX, kann außerdem #BEZUG! erscheinen.

Ergebnis #NV

VERGLEICH hat den Suchwert nicht gefunden. Häufige Gründe sind Tippfehler, Leerzeichen am Ende eines Eintrags oder Zahlen, die als Text gespeichert sind. Wenn fehlende Werte normal sind, fängst du den Fehler mit WENNFEHLER ab: =WENNFEHLER(INDEX(A2:A7;VERGLEICH(E2;B2:B7;0));"nicht gefunden").

INDEX und VERGLEICH auf Englisch

INDEX heißt in der englischen Version genauso, VERGLEICH heißt MATCH. Die Argumente werden mit Komma statt Semikolon getrennt:

Deutsch	Englisch
=INDEX(A2:A7;VERGLEICH(E2;B2:B7;0))	=INDEX(A2:A7,MATCH(E2,B2:B7,0))
XVERWEIS	XLOOKUP
XVERGLEICH	XMATCH
#NV	#N/A

Unsere Übungen verstehen beide Schreibweisen. Unter jeder Übung stellst du ein, welche Sprache dein Excel hat.

In welchen Excel-Versionen gibt es INDEX und VERGLEICH?

In allen, auch in Excel 2016 und 2019, in Excel für Mac und in Excel für das Web. Die Kombination ist deshalb die sichere Wahl für Dateien, die auch auf älteren Rechnern funktionieren müssen.

In Microsoft 365, Excel 2021 und Excel 2024 gibt es mit XVERWEIS eine kürzere Alternative. =XVERWEIS(E2;B2:B7;A2:A7) liefert dasselbe Ergebnis wie die Formel aus der ersten Übung, sucht standardmäßig genau und hat ein eigenes Argument für den Fall, dass nichts gefunden wird. In Excel 2019 und älter zeigt XVERWEIS allerdings nur #NAME?.

Häufige Fragen