Excel Textfunktionen: Text trennen, verbinden und bereinigen

Kurz gesagt: =LINKS(A2;3) holt die ersten drei Zeichen, =RECHTS(A2;4) die letzten vier und =TEIL(A2;5;4) vier Zeichen ab Position 5. Mit & hängst du Texte aneinander.

Probier es gleich aus

Jeder Artikelcode beginnt mit einem Kürzel für die Warengruppe. Hol dieses Kürzel mit einer Formel heraus. Die Formel wird danach für alle Zeilen ausgefüllt.

Aufgabe Die ersten drei Buchstaben jedes Artikelcodes stehen für die Warengruppe. Schreib in C2 eine Formel, die dieses Kürzel herausholt. Die Formel wird bis C7 nach unten ausgefüllt.

	A	B	C
1	Artikelcode	Artikel	Gruppe
2	PAP-1042	Kopierpapier A4
3	TEC-2210	USB-Stick 64 GB
4	FUR-3305	Bürostuhl
5	PAP-1187	Briefumschläge
6	TEC-2391	Webcam
7	FUR-3420	Rollcontainer

Die wichtigsten Textfunktionen

Funktion	Was sie tut	Beispiel mit A2 = „PAP-1042“
LINKS	Zeichen vom Anfang	=LINKS(A2;3) ergibt PAP
RECHTS	Zeichen vom Ende	=RECHTS(A2;4) ergibt 1042
TEIL	Zeichen ab einer Position	=TEIL(A2;5;2) ergibt 10
LÄNGE	Anzahl der Zeichen	=LÄNGE(A2) ergibt 8
FINDEN / SUCHEN	Position eines Zeichens	=FINDEN("-";A2) ergibt 4
GLÄTTEN	Entfernt Leerzeichen am Anfang und Ende und doppelte Leerzeichen dazwischen	=GLÄTTEN(A2)
GROSS / KLEIN / GROSS2	Alles groß, alles klein, Anfangsbuchstaben groß	=GROSS2("anna weber") ergibt Anna Weber
WECHSELN	Ersetzt einen Text durch einen anderen	=WECHSELN(A2;"-";"/") ergibt PAP/1042

Text an einem Trennzeichen teilen

LINKS und RECHTS reichen, solange die Teile immer gleich lang sind. Oft ist das nicht so, etwa bei „Anna Weber“ und „Jonas Hoffmann“. Dann suchst du zuerst mit FINDEN die Position des Trennzeichens und rechnest von dort aus:

• Vorname: =LINKS(A2;FINDEN(" ";A2)-1)
• Nachname: =TEIL(A2;FINDEN(" ";A2)+1;100)
• Alternativ: =RECHTS(A2;LÄNGE(A2)-FINDEN(" ";A2))

Die 100 bei TEIL ist einfach eine Zahl, die größer als jeder Nachname ist. TEIL gibt nie mehr Zeichen zurück, als vorhanden sind. FINDEN unterscheidet Groß- und Kleinschreibung, SUCHEN nicht. SUCHEN erlaubt außerdem Platzhalter wie * und ?. Ausführlich mit Übungen zu Text vor, nach und zwischen Zeichen: TEIL, FINDEN und SUCHEN.

Texte verbinden: &, TEXTKETTE und TEXTVERKETTEN

Das Zeichen & klebt Texte zusammen. Feste Texte wie Leerzeichen, Punkte oder Domains stehen in Anführungszeichen: =A2&" "&B2 ergibt „Anna Weber“. TEXTKETTE macht dasselbe als Funktion und nimmt auch ganze Bereiche: =TEXTKETTE(A2;" ";B2). Die ältere Funktion VERKETTEN funktioniert weiterhin, kann aber keine Bereiche.

TEXTVERKETTEN setzt ein Trennzeichen zwischen alle Werte und kann leere Zellen überspringen: =TEXTVERKETTEN(", ";WAHR;A2:A7) macht aus einer Spalte eine Liste wie „Anna, Tom, Lisa“.

Noch eine Übung: E-Mail-Adressen bauen

Ein Klassiker bei neuen Mitarbeitenden. Achte darauf, dass die Adresse am Ende komplett klein geschrieben ist.

Aufgabe Bilde in C2 die E-Mail-Adresse nach dem Muster vorname.nachname@firma.de, komplett in Kleinbuchstaben. Die Formel wird bis C7 nach unten ausgefüllt.

	A	B	C
1	Vorname	Nachname	E-Mail
2	Anna	Weber
3	Tom	Becker
4	Lisa	Wagner
5	Max	Hoffmann
6	Sara	Klein
7	Jonas	Fischer

Ohne Formel: Text in Spalten und Blitzvorschau

Wenn du Daten nur einmal aufteilen musst, brauchst du nicht unbedingt eine Formel. Unter Daten > Text in Spalten trennst du eine Spalte an einem Trennzeichen wie Leerzeichen, Komma oder Bindestrich in mehrere Spalten auf.

Noch schneller ist die Blitzvorschau: Schreib in die Spalte neben deinen Daten ein oder zwei Beispiele, etwa den Vornamen aus der ersten Zeile, und drück Strg+E. Excel erkennt das Muster und füllt den Rest aus. Beide Wege liefern feste Werte. Ändern sich die Ausgangsdaten, aktualisiert sich nichts. Dafür sind Formeln besser.

Typische Fehler bei Textfunktionen

Das Ergebnis ist Text, keine Zahl

=RECHTS(A2;4) liefert „1042“ als Text. Damit funktionieren SUMME und Vergleiche nicht wie erwartet. Mach eine Zahl daraus, indem du mit 1 multiplizierst: =RECHTS(A2;4)*1 oder =WERT(RECHTS(A2;4)).

#WERT! bei FINDEN

Kommt das gesuchte Zeichen nicht vor, liefert FINDEN #WERT!. Das passiert zum Beispiel bei einem Namen ohne Leerzeichen. Fang den Fall mit WENNFEHLER ab: =WENNFEHLER(LINKS(A2;FINDEN(" ";A2)-1);A2).

Unsichtbare Leerzeichen

Ein Leerzeichen am Ende reicht, damit „Berlin“ und „Berlin “ für Excel verschiedene Werte sind. Das ist auch ein häufiger Grund für #NV beim SVERWEIS. GLÄTTEN entfernt solche Leerzeichen. Aus Webseiten kopierte Daten enthalten manchmal geschützte Leerzeichen, die GLÄTTEN nicht erwischt: =GLÄTTEN(WECHSELN(A2;ZEICHEN(160);" ")).

Textfunktionen auf Englisch

In der englischen Excel-Version trennst du Argumente mit Komma statt Semikolon. Die Namen:

Deutsch	Englisch
LINKS, RECHTS, TEIL	LEFT, RIGHT, MID
LÄNGE, FINDEN, SUCHEN	LEN, FIND, SEARCH
GLÄTTEN, WECHSELN	TRIM, SUBSTITUTE
GROSS, KLEIN, GROSS2	UPPER, LOWER, PROPER
VERKETTEN, TEXTKETTE, TEXTVERKETTEN	CONCATENATE, CONCAT, TEXTJOIN
TEXTTEILEN, TEXTVOR, TEXTNACH	TEXTSPLIT, TEXTBEFORE, TEXTAFTER

In welchen Excel-Versionen gibt es die Textfunktionen?

LINKS, RECHTS, TEIL, LÄNGE, FINDEN, SUCHEN, GLÄTTEN, GROSS, KLEIN, GROSS2, WECHSELN und VERKETTEN gibt es in allen Versionen. TEXTKETTE und TEXTVERKETTEN kamen mit Excel 2019. Neu in Microsoft 365 und Excel 2024 sind TEXTTEILEN, TEXTVOR und TEXTNACH. =TEXTTEILEN(A2;" ") verteilt einen Namen direkt auf zwei Zellen, =TEXTNACH(A2;"-") liefert alles nach dem Bindestrich. Wenn du diese Funktionen hast, ersetzen sie viele Kombinationen aus TEIL und FINDEN.

Häufige Fragen