WENN mit UND und ODER: mehrere Bedingungen in Excel prüfen

Kurz gesagt: =UND(B2>=C2;D2>=4) ergibt WAHR, wenn beide Bedingungen stimmen. =ODER(B2>=50;C2="Premium") ergibt WAHR, wenn eine reicht. In WENN stehen sie an der Stelle der Prüfung: =WENN(UND(…);Dann_Wert;Sonst_Wert).

Probier es gleich aus

Einen Bonus gibt es nur, wenn zwei Dinge gleichzeitig stimmen: Das Umsatzziel ist erreicht und die Bewertung ist gut genug. Schreib die Formel für die erste Zeile, sie wird danach nach unten ausgefüllt.

Aufgabe Einen Bonus von 500 € gibt es nur, wenn der Umsatz mindestens das Ziel erreicht und die Bewertung mindestens 4 ist. Sonst gibt es 0. Schreib die Formel in E2, sie wird bis E7 ausgefüllt.

	A	B	C	D	E
1	Name	Umsatz €	Ziel €	Bewertung	Bonus €
2	Jana Weber	52400	50000	4
3	Murat Kaya	61800	55000	3
4	Lena Hoffmann	47300	50000	5
5	Tom Schulz	58000	58000	4
6	Sara Klein	39900	45000	2
7	Ali Demir	66100	60000	5

So arbeiten UND, ODER und NICHT

Alle drei Funktionen liefern kein Ergebnis wie eine Zahl oder einen Text, sondern nur WAHR oder FALSCH. Jede Bedingung ist ein Vergleich, wie du ihn aus der WENN-Funktion kennst, und die Bedingungen trennst du mit Semikolon.

Funktion	Ergibt WAHR, wenn …	Beispiel
UND	alle Bedingungen wahr sind	=UND(B2>=C2;D2>=4)
ODER	mindestens eine Bedingung wahr ist	=ODER(B2>=50;C2="Premium")
NICHT	die Bedingung falsch ist (dreht das Ergebnis um)	=NICHT(C2="Premium")

UND und ODER nehmen bis zu 255 Bedingungen. Bei zwei Bedingungen hilft diese Merkregel: UND ist streng, ein einziges FALSCH macht das Ganze FALSCH. ODER ist großzügig, ein einziges WAHR reicht.

UND und ODER in WENN einsetzen

Allein zeigt UND nur WAHR oder FALSCH. Meist willst du aber einen Text oder Betrag sehen. Dafür setzt du UND oder ODER als Prüfung in WENN ein:

• =WENN(UND(B2>=C2;D2>=4);500;0) zahlt 500 € Bonus, wenn das Ziel erreicht ist und die Bewertung mindestens 4 beträgt.
• =WENN(ODER(B2>=50;C2="Premium");0;4,95) macht den Versand kostenlos, wenn der Betrag mindestens 50 € ist oder ein Premium-Kunde bestellt.
• =WENN(NICHT(C2="erledigt");"offen";"") zeigt „offen“ bei allem, was noch nicht erledigt ist. Dasselbe erreichst du kürzer mit C2<>"erledigt".

Achte auf die Klammern: UND bekommt seine eigene Klammer, danach folgt das Semikolon für den Dann_Wert von WENN. Ein typischer Tippfehler ist =WENN(UND(B2>=C2;D2>=4;500;0)). Dann landen 500 und 0 als weitere Bedingungen in UND, und WENN fehlt der Dann_Wert.

Noch eine Übung: Versandkosten mit ODER

Diesmal reicht eine von zwei Bedingungen. Achte auf die Bestellung mit genau 50 €.

Aufgabe Der Versand ist kostenlos, wenn der Bestellbetrag mindestens 50 € beträgt oder die Kundenart Premium ist. Sonst kostet er 4,95 €. Schreib die Formel in D2, sie wird bis D8 ausgefüllt.

	A	B	C	D
1	Bestellung	Betrag €	Kundenart	Versand €
2	B-1043	72,5	Standard
3	B-1038	38,9	Premium
4	B-1051	24	Standard
5	B-1029	50	Standard
6	B-1047	129,99	Premium
7	B-1055	45,1	Standard
8	B-1032	18,75	Premium

UND und ODER kombinieren

Du kannst die Funktionen ineinander setzen. Ein Bonus für alle aus dem Vertrieb, die entweder ihr Ziel erreicht haben oder mehr als 20 Neukunden gewonnen haben:

=WENN(UND(A2="Vertrieb";ODER(B2>=C2;D2>20));"Bonus";"")

Lies solche Formeln von innen nach außen: Erst wertet Excel das ODER aus, dann das UND mit dem Ergebnis. Bei mehr als zwei Ebenen lohnt sich oft eine Hilfsspalte, in der jede Teilprüfung einzeln steht. Das ist leichter zu kontrollieren.

UND als Regel für die bedingte Formatierung

Weil UND schon WAHR oder FALSCH liefert, brauchst du für eine Regel der bedingten Formatierung kein WENN. Die Regel markiert jede Zelle, für die die Formel WAHR ergibt. Mit $ vor dem Spaltenbuchstaben färbt sie die ganze Zeile.

Aufgabe Markiere mit bedingter Formatierung die ganzen Zeilen A2:C8 der Rechnungen, die mindestens 1000 € betragen und länger als 30 Tage offen sind. Schreib die Formel der Regel so, wie sie für die erste Zelle A2 gilt.

	A	B	C
1	Rechnung	Betrag €	Tage offen
2	R-2041	1850	45
3	R-2038	420	62
4	R-2050	2300	12
5	R-2033	1000	31
6	R-2047	760	8
7	R-2029	3150	74
8	R-2052	1290	30

Dieselbe Formel ohne Formatierung in einer eigenen Spalte ergibt eine Prüfspalte mit WAHR und FALSCH. Die kannst du filtern oder mit ZÄHLENWENN auswerten. Willst du direkt Beträge mit mehreren Bedingungen addieren, ist SUMMEWENNS der kürzere Weg.

Typische Fehler mit UND und ODER

Den Wert zweimal vergleichen wollen

=UND(B2>=1000;<=5000) funktioniert nicht. Jede Bedingung braucht ihren eigenen vollständigen Vergleich: =UND(B2>=1000;B2<=5000). Auch B2="Berlin";"Hamburg" ist kein gültiges ODER, richtig ist ODER(B2="Berlin";B2="Hamburg").

UND und ODER verwechselt

Umgangssprachlich sagt man „Kunden aus Berlin und Hamburg“, gemeint ist aber jeder, der aus einer der beiden Städte kommt. Eine Zelle kann nicht gleichzeitig Berlin und Hamburg enthalten, mit UND wäre das Ergebnis immer FALSCH. Frag dich bei jeder Zeile: Muss alles stimmen oder reicht eins?

Text ohne Anführungszeichen

C2=Premium ergibt #NAME?, weil Excel Premium für einen Namen hält. Texte stehen immer in geraden Anführungszeichen: C2="Premium". Groß- und Kleinschreibung spielt dabei keine Rolle.

UND, ODER und NICHT auf Englisch

In der englischen Excel-Version trennst du Argumente mit Komma statt Semikolon. Die Namen:

Deutsch	Englisch
UND, ODER, NICHT	AND, OR, NOT
XODER	XOR
WAHR, FALSCH	TRUE, FALSE
=WENN(UND(B2>=C2;D2>=4);500;0)	=IF(AND(B2>=C2,D2>=4),500,0)

Unsere Übungen verstehen beide Schreibweisen. Unter jeder Übung stellst du ein, welche Sprache dein Excel hat.

In welchen Excel-Versionen gibt es UND und ODER?

UND, ODER und NICHT gibt es in allen Excel-Versionen, auch in Excel 2016, in Excel für Mac und in Excel für das Web. Wenn du eine Datei weitergibst, musst du dir bei diesen drei Funktionen also keine Gedanken machen. XODER ist WAHR, wenn eine ungerade Anzahl Bedingungen stimmt, bei zwei Bedingungen also genau eine. Microsoft führt XODER für Excel 2016 und neuer sowie Microsoft 365 auf.

Häufige Fragen