Rounding in Excel: ROUND, ROUNDUP and ROUNDDOWN
ROUND, ROUNDUP and ROUNDDOWN decide how many digits a number keeps and which way it goes. Think unit prices to the cent, or the number of boxes an order fills.
In short: =ROUND(A2,2) rounds to two decimal places, =ROUNDUP(A2,0) always goes up to a whole number, =ROUNDDOWN(A2,0) always goes down. =ROUND(A2,-2) rounds to the nearest hundred.
Try it now
A price list needs the price per unit, but pack price divided by units per pack often runs to four decimals or more. Round the result to the cent.
Task The price list needs a unit price: pack price divided by units per pack. Calculate it in D2 and round it to two decimal places. The formula is filled down to D7.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Item | Pack price $ | Units per pack | Unit price $ |
| 2 | Ballpoint pens | 12.99 | 20 | |
| 3 | Sticky notes | 8.49 | 12 | |
| 4 | Highlighters | 7.99 | 6 | |
| 5 | Binders | 18.75 | 10 | |
| 6 | Tape | 9.95 | 8 | |
| 7 | Envelopes | 14.49 | 50 |
How the ROUND function works
ROUND, ROUNDUP and ROUNDDOWN all take the same two arguments. Only the direction differs.
| Argument | What it means | In the example |
|---|---|---|
| number | The value or calculation you want to round | B2/C2, i.e. 12.99 divided by 20 |
| num_digits | How many decimal places to keep. 0 gives a whole number, negative values round to the left of the decimal point. | 2 for cents |
Here is what num_digits does to 1234.567:
| Formula | Result |
|---|---|
=ROUND(1234.567,2) | 1234.57 |
=ROUND(1234.567,0) | 1235 |
=ROUND(1234.567,-1) | 1230 |
=ROUND(1234.567,-2) | 1200 |
=ROUND(1234.567,-3) | 1000 |
ROUND vs ROUNDUP vs ROUNDDOWN vs INT
ROUND goes up from 5 and down below it. ROUNDUP always moves away from zero, ROUNDDOWN always toward zero. INT has no second argument and returns the next whole number down, which makes it behave differently from ROUNDDOWN on negative numbers.
| Function | 3.2 | 3.7 | -3.7 |
|---|---|---|---|
ROUND(x,0) | 3 | 4 | -4 |
ROUNDUP(x,0) | 4 | 4 | -4 |
ROUNDDOWN(x,0) | 3 | 3 | -3 |
INT(x) | 3 | 3 | -4 |
Practice: how many boxes?
Standard rounding gives the wrong answer here. Even one leftover unit needs another box.
Task For shipping you need to know how many boxes each order takes. A partly filled box still counts as a whole box. Calculate the number in D2. The formula is filled down to D7.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Item | Order quantity | Units per box | Boxes |
| 2 | Copy paper | 250 | 24 | |
| 3 | Toner | 120 | 12 | |
| 4 | Binders | 75 | 40 | |
| 5 | Ballpoint pens | 1000 | 144 | |
| 6 | Hole punches | 36 | 50 | |
| 7 | Notepads | 480 | 36 |
Round to the nearest 10, 100 or 1000
Budgets, forecasts and slides usually want round numbers. Use a negative num_digits: -1 rounds to tens, -2 to hundreds, -3 to thousands. This works with all three functions, so =ROUNDUP(A2,-2) always goes up to the next full hundred. You can also wrap a whole calculation in ROUND.
Task For budget planning you need the total of all costs, rounded to the nearest hundred. Calculate it in B9 with a single formula.
| A | B | |
|---|---|---|
| 1 | Department | Costs 2026 $ |
| 2 | Sales | 18435 |
| 3 | HR | 9260 |
| 4 | IT | 12780 |
| 5 | Purchasing | 7345 |
| 6 | Logistics | 15910 |
| 7 | Finance | 4630 |
| 8 | ||
| 9 | Budget 2027 (rounded) |
Round to the nearest 5 cents, 50 cents or .99
For multiples there is MROUND: =MROUND(A2,0.05) rounds to the nearest 5 cents, =MROUND(A2,5) to the nearest 5 dollars. Microsoft notes that when the multiple has decimals, values exactly halfway can go either way, and number and multiple must have the same sign or you get #NUM!. A reliable alternative for 5 cents is =ROUND(A2*20,0)/20, since a dollar has twenty 5-cent steps.
To always round up to the next multiple, use =CEILING.MATH(A2,0.05), and =FLOOR.MATH(A2,0.05) to always round down. Prices ending in .99 come from =ROUNDUP(A2,0)-0.01.
Formatting only hides decimals
Decrease Decimal or a number format such as 0.00 makes a number look rounded, but the cell still holds the full value and Excel keeps calculating with it. That is where totals that do not add up come from: three cells holding 0.333, formatted to two places, read 0.33 + 0.33 + 0.33, yet their sum shows 1.00. When an amount has to be rounded for real, on an invoice for example, use ROUND.
Common mistakes
Leaving out num_digits
In Excel the second argument of ROUND is required, so =ROUND(A2) will not be accepted. Use 0 for whole numbers.
Rounding at the wrong step
Rounding every line and then adding can give a total a few cents off the rounded grand total. Decide where rounding belongs. Invoices usually round each line and then add, reports usually round only the final figure.
ROUND where you need ROUNDUP
Boxes, pallets and started hours always go up. ROUND turns 10.2 boxes into 10.
Too few digits on a percentage
21.8% is stored as 0.218, which has three decimals. =ROUND(B2,1) would turn that share into 0.2. The percentages lesson explains how Excel stores them.
Rounding functions in German Excel
German Excel separates arguments with semicolons and uses a comma as the decimal separator, so =ROUND(A2,2) becomes =RUNDEN(A2;2).
| English | German |
|---|---|
| ROUND | RUNDEN |
| ROUNDUP, ROUNDDOWN | AUFRUNDEN, ABRUNDEN |
| INT, TRUNC | GANZZAHL, KÜRZEN |
| MROUND | VRUNDEN |
| CEILING.MATH, FLOOR.MATH | OBERGRENZE.MATHEMATIK, UNTERGRENZE.MATHEMATIK |
Which Excel versions have these functions?
ROUND, ROUNDUP, ROUNDDOWN, INT and TRUNC exist in every version of Excel for Windows and Mac and in Excel for the web. Microsoft lists MROUND, CEILING.MATH and FLOOR.MATH for Microsoft 365, Excel 2024, 2021, 2019 and 2016, on Windows and Mac.
Frequently asked questions
How do I round to 2 decimal places in Excel?
Use =ROUND(A2,2). If the value comes from a calculation, put it inside: =ROUND(B2*C2,2).
How do I round to the nearest 10 or 100?
Give ROUND a negative number of digits: =ROUND(A2,-1) for tens, =ROUND(A2,-2) for hundreds. Use ROUNDUP with the same digits to always go up.
Does Excel always round .5 up?
ROUND moves halves away from zero: 2.5 becomes 3 and -2.5 becomes -3. Excel does not use round-half-to-even, which some statistics tools apply.
What is the difference between INT and TRUNC?
For positive numbers, none: both drop the decimals. For negative numbers INT rounds down (-3.7 becomes -4), while TRUNC simply cuts (-3.7 becomes -3).
Why does my total not match the numbers on screen?
The numbers are formatted, not rounded, so Excel adds the full values. Round the individual values with ROUND if the total has to match what you see.