Chi-Quadrat-Test in Excel

Kurz gesagt: Du brauchst zwei gleich große Tabellen, die beobachteten Häufigkeiten und die erwarteten. Die erwartete Häufigkeit einer Zelle ist Zeilensumme mal Spaltensumme durch Gesamtsumme. =CHIQU.TEST(Beobachtet;Erwartet) gibt dann den p-Wert zurück. Ist er kleiner als 0,05, hängen die beiden Merkmale vermutlich zusammen.

Probier es gleich aus

Ein Newsletter ging mit zwei Betreffzeilen an je 200 Leute. Die erwarteten Häufigkeiten stehen schon da. Klick in die gelbe Zelle und berechne den p-Wert.

Aufgabe Ein Newsletter ging mit zwei Betreffzeilen an je 200 Leute. Oben steht, wie viele geklickt haben, unten die erwarteten Häufigkeiten, falls der Betreff keine Rolle spielt. Berechne in F2 mit dem Chi-Quadrat-Test den p-Wert.

	A	B	C	D	E	F
1	Beobachtet	Geklickt	Nicht geklickt
2	Betreff A	48	152		p-Wert
3	Betreff B	72	128
4
5	Erwartet	Geklickt	Nicht geklickt
6	Betreff A	60	140
7	Betreff B	60	140

So funktioniert der Chi-Quadrat-Test

Der Test vergleicht, was du beobachtet hast, mit dem, was du erwarten würdest, wenn die beiden Merkmale nichts miteinander zu tun hätten (Nullhypothese: Unabhängigkeit). Insgesamt haben 120 von 400 Leuten geklickt, also 30 %. Wäre der Betreff egal, hätten von jeweils 200 Empfängern 60 klicken müssen. Beobachtet wurden 48 und 72.

Schritt	Formel	Im Beispiel
Erwartete Häufigkeit je Zelle	Zeilensumme · Spaltensumme / Gesamtsumme	200 · 120 / 400 = 60
Abweichung je Zelle	(Beobachtet - Erwartet)² / Erwartet	(48 - 60)² / 60 = 2,4
Prüfgröße Chi-Quadrat	Summe aller Abweichungen	6,86
Freiheitsgrade	(Zeilen - 1) · (Spalten - 1)	1
p-Wert	=CHIQU.TEST(B2:C3;B6:C7)	0,0088

CHIQU.TEST erledigt die letzten drei Schritte in einem. Die Prüfgröße selbst zeigt Excel nicht an. Du kannst sie aber mit =SUMMENPRODUKT((B2:C3-B6:C7)^2/B6:C7) nachrechnen oder aus dem p-Wert zurückgewinnen: =CHIQU.INV.RE(F2;1) ergibt ebenfalls 6,86.

Den p-Wert deuten

p = 0,0088 heißt: Wäre der Betreff egal, käme eine mindestens so große Abweichung von den erwarteten Zahlen in weniger als 1 % der Fälle vor. Bei einem Signifikanzniveau von 5 % verwirfst du die Annahme der Unabhängigkeit. Betreff B mit 36 % Klickrate schneidet besser ab als Betreff A mit 24 %. Wie beim t-Test gilt: Der p-Wert sagt nichts darüber, wie groß der Unterschied ist, und er sagt nichts über die Ursache. Die Klickraten selbst gehören deshalb immer mit in den Bericht.

Noch eine Übung: erwartete Häufigkeiten berechnen

Die erwarteten Werte rechnest du am besten mit einer einzigen Formel, die du über die ganze Tabelle ausfüllst. Damit das klappt, brauchst du gemischte Bezüge.

Aufgabe Oben siehst du, welche Tarife Kunden in zwei Regionen gewählt haben, mit Zeilen- und Spaltensummen. Berechne in B8 die erwartete Häufigkeit für Nord und Basis: Zeilensumme mal Spaltensumme durch Gesamtsumme. Die Formel wird danach bis D9 ausgefüllt und muss in jeder Zelle stimmen.

	A	B	C	D	E
1		Basis	Plus	Premium	Summe
2	Nord	38	45	17	100
3	Süd	32	65	23	120
4	Summe	70	110	40	220
5
6
7	Erwartet	Basis	Plus	Premium
8	Nord
9	Süd

Diese Übung gehört zu Premium.

Mit Premium öffnest du alle Übungen jeder Lektion, übst unbegrenzt mit neuen Aufgaben und kannst den Abschlusstest mit Zertifikat machen.

Premium ansehen Schon Premium? Anmelden

Die erste Übung dieser Lektion ist kostenlos.

Mit =$E2*B$4/$E$4 bleibt beim Ausfüllen nach rechts die Spalte E fest, beim Ausfüllen nach unten die Zeile 4. Für diese Tarifdaten ergibt =CHIQU.TEST(B2:D3;B8:D9) einen p-Wert von 0,196 bei 2 Freiheitsgraden. Das ist kein signifikanter Zusammenhang: Die Unterschiede zwischen Nord und Süd können gut Zufall sein. Kommen deine Rohdaten als lange Liste, zählst du sie vorher mit einer PivotTable oder ZÄHLENWENNS zu einer Kreuztabelle zusammen.

Voraussetzungen

• Erwartete Häufigkeiten nicht zu klein: Microsoft weist darauf hin, dass der Test nur passt, wenn die erwarteten Werte nicht zu klein sind. Eine gängige Faustregel verlangt mindestens 5 in jeder Zelle. Sonst Kategorien zusammenfassen oder einen exakten Test in einem Statistikprogramm nutzen.
• Absolute Zahlen: Der Test braucht Anzahlen, keine Prozente oder Mittelwerte. 24 % und 36 % ergeben ohne die 200 Empfänger keinen sinnvollen Test.
• Unabhängige Beobachtungen: Jede Person darf nur in einer Zelle stehen. Wer beide Newsletter bekommen hat, verfälscht den Test.

Für 2×2-Tabellen wenden manche Statistikprogramme automatisch die Yates-Korrektur an. CHIQU.TEST tut das nicht. Im Newsletter-Beispiel läge der korrigierte p-Wert bei 0,012 statt 0,0088. Wundere dich also nicht, wenn ein anderes Programm leicht abweicht.

Anpassungstest: eine Zeile gegen eine Erwartung

CHIQU.TEST funktioniert auch mit nur einer Zeile oder Spalte, etwa Beschwerden je Wochentag gegen eine gleichmäßige Verteilung. Die Freiheitsgrade sind dann Anzahl der Zellen minus 1. Die erwarteten Werte kommen hier nicht aus Summen, sondern aus deiner Annahme, zum Beispiel Gesamtzahl durch 5 für fünf Wochentage.

Typische Fehler

Summenzeile mit im Bereich

Beobachtet und Erwartet umfassen nur die Datenzellen, nie die Zeilen- oder Spaltensummen.

Unterschiedlich große Bereiche

Haben beide Bereiche nicht gleich viele Zellen, gibt CHIQU.TEST #NV zurück.

Ergebnis als Chi-Quadrat-Wert gelesen

CHIQU.TEST liefert den p-Wert, nicht die Prüfgröße.

Chi-Quadrat-Test auf Englisch

Deutsch	Englisch
=CHIQU.TEST(B2:C3;B6:C7)	=CHISQ.TEST(B2:C3,B6:C7)
CHIQU.INV.RE, CHIQU.VERT.RE	CHISQ.INV.RT, CHISQ.DIST.RT
SUMMENPRODUKT	SUMPRODUCT

Im englischen Excel trennst du die Argumente mit Komma.

In welchen Excel-Versionen gibt es CHIQU.TEST?

CHIQU.TEST gibt es laut Microsoft seit Excel 2010. Die Hilfe führt die Funktion für Microsoft 365, Excel 2024, 2021, 2019 und 2016, auch für den Mac. Die ältere Funktion CHITEST rechnet gleich und bleibt als Kompatibilitätsfunktion erhalten. Die Analyse-Funktionen haben kein eigenes Tool für den Chi-Quadrat-Test, die Formel ist der Weg.

Häufige Fragen