Excel-Formeln: Übersicht und Formelsammlung
Eine Formel ist alles, was in einer Zelle mit = beginnt. Hier siehst du, wie Formeln aufgebaut sind, wie du sie eingibst, und welche Excel-Funktionen du im Alltag wirklich brauchst, sortiert nach Aufgabe und jeweils mit Beispiel.
Kurz gesagt: Jede Excel-Formel beginnt mit =. Danach folgen Zellbezüge wie B2, Rechenzeichen wie + oder * und Funktionen wie =SUMME(B2:B7). Die wichtigsten Formeln im Alltag sind SUMME, MITTELWERT, WENN, ZÄHLENWENN, SUMMEWENN und SVERWEIS oder XVERWEIS.
Probier es gleich aus: deine erste Formel
Menge mal Preis für jede Zeile einer Bestellung. Die Formel schreibst du einmal, Excel füllt sie nach unten aus.
Aufgabe Berechne in D2 den Umsatz für das Druckerpapier: Menge mal Preis. Die Formel wird danach bis D7 nach unten ausgefüllt und muss in jeder Zeile stimmen.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Artikel | Menge | Preis € | Umsatz € |
| 2 | Druckerpapier | 40 | 4,99 | |
| 3 | Toner | 6 | 59,9 | |
| 4 | Ordner | 25 | 2,49 | |
| 5 | Kugelschreiber | 120 | 0,79 | |
| 6 | Haftnotizen | 30 | 1,89 | |
| 7 | USB-Stick | 10 | 8,5 |
So ist eine Excel-Formel aufgebaut
| Teil | Bedeutung | Beispiel |
|---|---|---|
| = | Startet jede Formel. Ohne = ist der Eintrag nur Text. | =B2*C2 |
| Zellbezug | Verweist auf eine Zelle. Ändert sich ihr Wert, rechnet die Formel neu. | B2 |
| Bereich | Mehrere Zellen von einer Ecke bis zur anderen, getrennt durch Doppelpunkt | B2:B7 |
| Rechenzeichen | Plus, Minus, Mal, Geteilt, Hoch | + - * / ^ |
| Funktion | Fertige Rechnung mit Namen, die Argumente in Klammern bekommt | SUMME(B2:B7) |
| Argumente | Die Angaben in der Klammer, im deutschen Excel durch Semikolon getrennt | RUNDEN(B2;2) |
Formel und Funktion werden oft gleich benutzt. Genau genommen ist die Formel der ganze Eintrag in der Zelle, die Funktion ist ein Baustein darin. =SUMME(B2:B7)*1,19 ist eine Formel mit der Funktion SUMME.
Formel eingeben: Schritt für Schritt
- Klick in die Zelle, in der das Ergebnis stehen soll.
- Tipp = ein.
- Klick die erste Zelle an, die du brauchst, oder tipp ihre Adresse. Excel umrandet sie farbig.
- Tipp das Rechenzeichen oder den Funktionsnamen. Schon nach den ersten Buchstaben schlägt Excel passende Funktionen vor, mit Tab übernimmst du den Vorschlag.
- Drück die Eingabetaste. In der Zelle steht das Ergebnis, die Formel siehst du oben in der Bearbeitungsleiste.
Zum Ändern klickst du in die Bearbeitungsleiste oder drückst F2. Für die gleiche Formel in vielen Zeilen ziehst du das kleine Quadrat unten rechts an der Zelle nach unten oder doppelklickst es. Dabei passen sich die Bezüge an, B2 wird zu B3, B4 und so weiter. Soll ein Bezug fest bleiben, setzt du Dollarzeichen: absolute Bezüge. Eine Summe über die Zahlen darüber setzt die AutoSumme mit Alt+Umschalt+0. Alle Formeln eines Blatts auf einmal siehst du auf der Registerkarte Formeln mit Formeln anzeigen.
Rechenzeichen und Operatoren in Excel
| Zeichen | Bedeutung | Beispiel |
|---|---|---|
| + - | Plus, Minus | =B2+C2, =C2-B2 |
| * / | Mal, Geteilt | =B2*C2, =C2/B2 |
| ^ | Hoch (Potenz) | =B2^2 |
| % | Prozent, teilt durch 100 | =B2*19% |
| & | Text verbinden | =A2&" "&B2 |
| = <> > < >= <= | Vergleich, ergibt WAHR oder FALSCH | =C2>=1000 |
| : | Bereich | B2:B7 |
Die Reihenfolge laut Microsoft: Bezüge, dann Vorzeichen, Prozent, Potenz, Punkt- vor Strichrechnung, dann & und zuletzt Vergleiche. Gleichrangiges rechnet Excel von links nach rechts. Mit Klammern legst du die Reihenfolge selbst fest: =(B2+C2)*D2.
Die wichtigsten Excel-Formeln nach Zweck
Die Liste deckt ab, was im Büro, in der Ausbildung und in Einstellungstests am häufigsten vorkommt. Jeder Name führt zu einer Lektion mit Erklärung und Übungen.
Rechnen und summieren
| Formel | Zweck | Beispiel |
|---|---|---|
| + - * / | Grundrechenarten | =B2*C2 |
| SUMME | Werte addieren | =SUMME(B2:B7) |
| Prozent | Anteil, Aufschlag, Veränderung | =C2/B2-1 |
| RUNDEN | auf Stellen runden | =RUNDEN(B2;2) |
| POTENZ, WURZEL, ABS, REST | Potenz, Wurzel, Betrag, Rest | =ABS(C2-B2) |
| SUMMENPRODUKT | Menge mal Preis summieren, gewichteter Mittelwert | =SUMMENPRODUKT(B2:B7;C2:C7) |
| TEILERGEBNIS | nur sichtbare Zeilen auswerten | =TEILERGEBNIS(109;C2:C50) |
| ZW, RMZ | Zinseszins, Kreditrate | =RMZ(B2/12;B3*12;-B1) |
Zählen, Durchschnitt, Rang
| Formel | Zweck | Beispiel |
|---|---|---|
| MITTELWERT | Durchschnitt | =MITTELWERT(B2:B7) |
| ANZAHL, ANZAHL2 | Zahlen oder gefüllte Zellen zählen | =ANZAHL2(A2:A50) |
| KGRÖSSTE, RANG.GLEICH | Top-Werte und Platzierung | =KGRÖSSTE(C2:C9;2) |
Wenn-dann und Bedingungen
| Formel | Zweck | Beispiel |
|---|---|---|
| WENN | Wenn-dann-sonst | =WENN(C2>=1000;"Bonus";"") |
| UND, ODER | mehrere Bedingungen verknüpfen | =UND(B2>0;C2="Nord") |
| WENNS | mehrere Stufen ohne Verschachteln | =WENNS(B2>=90;"A";B2>=75;"B";WAHR;"C") |
| WENNFEHLER | Fehlerwert durch Ersatz ersetzen | =WENNFEHLER(C2/B2;0) |
| ZÄHLENWENN, ZÄHLENWENNS | zählen mit einer oder mehreren Bedingungen | =ZÄHLENWENN(A2:A50;"Berlin") |
| SUMMEWENN, SUMMEWENNS | summieren mit Bedingungen | =SUMMEWENN(A2:A50;"Berlin";C2:C50) |
| MITTELWERTWENN | Durchschnitt mit Bedingung | =MITTELWERTWENN(B2:B50;"IT";C2:C50) |
| MAXWENNS, MINWENNS | größter oder kleinster Wert mit Bedingung | =MAXWENNS(C2:C50;A2:A50;"Nord") |
Nachschlagen und verweisen
| Formel | Zweck | Beispiel |
|---|---|---|
| SVERWEIS | Wert zu einem Suchbegriff aus einer Liste holen | =SVERWEIS(E2;A2:C50;3;FALSCH) |
| XVERWEIS | moderner Nachfolger, sucht in jede Richtung | =XVERWEIS(E2;A2:A50;C2:C50) |
| INDEX und VERGLEICH | flexibles Nachschlagen in allen Versionen | =INDEX(C2:C50;VERGLEICH(E2;A2:A50;0)) |
| MTRANS | Zeilen und Spalten tauschen | =MTRANS(A1:E4) |
Text, Datum und Listen
| Formel | Zweck | Beispiel |
|---|---|---|
| &, TEXTVERKETTEN | Texte zusammensetzen | =A2&" "&B2 |
| LINKS, RECHTS, LÄNGE | Teile eines Textes, Zeichen zählen | =LINKS(A2;3) |
| TEIL, FINDEN | Text an einer Stelle herausschneiden | =TEIL(A2;FINDEN("@";A2)+1;50) |
| WECHSELN, GLÄTTEN | Text bereinigen | =GLÄTTEN(A2) |
| DATUM, MONAT, JAHR | mit Datumswerten rechnen | =MONAT(A2) |
| DATEDIF, NETTOARBEITSTAGE | Abstand in Jahren, Monaten, Arbeitstagen | =NETTOARBEITSTAGE(A2;B2) |
| FILTER, SORTIEREN, EINDEUTIG | Listen filtern und sortieren per Formel | =EINDEUTIG(A2:A50) |
Noch eine Übung: SUMME
Die Formel, die du am häufigsten schreiben wirst. Addiere die Ausgaben von sechs Monaten.
Aufgabe Berechne in B9 mit SUMME die Ausgaben für Büromaterial im ersten Halbjahr.
| A | B | |
|---|---|---|
| 1 | Monat | Ausgaben € |
| 2 | Januar | 1240 |
| 3 | Februar | 980 |
| 4 | März | 1105 |
| 5 | April | 1320 |
| 6 | Mai | 1015 |
| 7 | Juni | 1190 |
| 8 | ||
| 9 | Summe: |
Typische Fehler bei Formeln
Die Formel steht als Text in der Zelle
Fehlt das = am Anfang oder war die Zelle vorher als Text formatiert, zeigt Excel die Formel statt des Ergebnisses. Stell das Format auf Standard und bestätige die Formel neu mit F2 und Eingabe.
#NAME? statt Ergebnis
Excel kennt einen Namen nicht, meist ein Tippfehler oder ein englischer Funktionsname im deutschen Excel. Alle Fehlerwerte erklärt die Seite Fehlerwerte in Excel.
Komma statt Semikolon
Im deutschen Excel trennt das Semikolon die Argumente, das Komma ist das Dezimalzeichen. Formeln aus englischen Anleitungen musst du deshalb umschreiben.
Excel-Formeln auf Englisch
Im englischen Excel heißen die meisten Funktionen anders: SUMME ist SUM, WENN ist IF, SVERWEIS ist VLOOKUP, und Argumente trennt ein Komma. Die vollständige Liste mit allen Namen steht unter Excel-Funktionen Englisch und Deutsch.
Häufige Fragen
Was ist der Unterschied zwischen Formel und Funktion?
Die Formel ist der ganze Eintrag ab dem =. Eine Funktion wie SUMME oder WENN ist ein fertiger Baustein, den du in einer Formel benutzt. =B2*C2 ist eine Formel ohne Funktion.
Was sind die 10 wichtigsten Excel-Formeln?
Für den Einstieg: die Grundrechenarten mit Zellbezügen, SUMME, MITTELWERT, ANZAHL, RUNDEN, WENN, ZÄHLENWENN, SUMMEWENN, SVERWEIS oder XVERWEIS und WENNFEHLER. Damit löst du den Großteil typischer Büroaufgaben. Danach lohnen sich SUMMEWENNS, INDEX und VERGLEICH und die Textfunktionen.
Sind Excel-Befehle und Excel-Formeln dasselbe?
Nein. Befehle sind die Schaltflächen und Menüs, etwa Sortieren, Filter oder Inhalte einfügen. Sie verändern die Tabelle einmal, wenn du klickst. Eine Formel steht in einer Zelle und rechnet jedes Mal neu, wenn sich die Daten ändern. Für viele Aufgaben gibt es beides, zum Beispiel Transponieren als Befehl und MTRANS als Formel.
Gibt es eine Excel-Formelsammlung zum Ausdrucken?
Diese Übersicht kannst du mit Strg+P drucken oder als PDF speichern. Üben solltest du die Formeln trotzdem, denn beim Schreiben merkst du sie dir viel besser als beim Lesen.
Warum rechnet meine Formel nicht neu?
Prüf unter Formeln, Berechnungsoptionen, ob Automatisch eingestellt ist. Steht dort Manuell, rechnet Excel erst nach F9.
Wo finde ich alle Excel-Funktionen?
Unter Formeln, Funktion einfügen oder über die Schaltfläche fx neben der Bearbeitungsleiste. Dort kannst du nach Kategorie suchen und bekommst zu jeder Funktion die Argumente erklärt.